consulta sobre notepad y atr

[dogdark]

La consulta es referente a que varias veces e visto a vitoco tomar código de un atr y pasarlo al notepad entonces así copia y modifica lo que quiere, la pregunta es como lo hace?? como abre ese atr con el notepad, la otra vez solo lo vi pero el muy pavo de mi no se me ocurrió preguntarle, podrían hechar una mano y enseñar de como se obtienen esos códigos en el notepad, la idea es tomar el código de algunos juegos y retirarle partes para ver que pasa, o sea cachurear, de antemano se agradece.

[vitoco]

Los verdaderos hackers editan binarios con "vi"...

Lo que yo hice en la junta, fue usar un editor que permite modificar archivos binarios, es decir, los carga sin alterar su contenido (no tiene sentido hablar de codificación ANSI, UTF-8 y demases), y que además provee una visualización simultánea en hexadecimal. Por lo tanto, pude abrir 2 archivos ATR al mismo tiempo y copiar los 3 sectores boot de uno (con makemenu) y ponerlos en el otro (recién formateado y con un XEX adentro). Eso fue trivial, porque no alteraba la estructura ni el tamaño del archivo, sino sólo su contenido en sectores estándares para DOS y makemenu (los primeros 3x128=384 bytes saltándose los 16 bytes de encabezado propio de los ATR).

Editores para Windows y otros ambientes que permiten hacer lo anterior hay muchos... algunos gratis y otros no tanto.

Ediciones más rebuscadas habrían sido otras como cambiar los créditos, pero para eso tengo el "Buscador" en Atari para resolver cosas como los desfaces del ATASCII y del código interno para ANTIC.

[josepzin]

Sí que hay muchos editores de esos!

Yo tengo a mano un par.

[dogdark]

pero el programa que usaste fue el Notepad++ con algún plugin adicional que te permitía hacer eso o fue otro editor especial?

[vitoco]

pero el programa que usaste fue el Notepad++ con algún plugin adicional que te permitía hacer eso o fue otro editor especial?

El Notepad++ requiere de un plugin que viene en un pack. Yo usé el Ultraedit ese día.

[dogdark]

gracias vitoco, ahí veré que hago para aprender

[AsCrNet]

aja me acorde que alguna vez hice un makemenu-pc eso para no estar weviando.

Saludos

[vitoco]

aja me acorde que alguna vez hice un makemenu-pc eso para no estar weviando.

No recuerdo haber visto ese MakeMenú con letras:



¿Cuántos juegos aguanta por disco? ¿Los 26 de la A a la Z? ¿También son sólo 3 sectores?

En todo caso, lo que dogdark me vio hacer fue un merge de dos ATRs

[AsCrNet]

No recuerdo haber visto ese MakeMenú con letras

Este fue publicado en la revista STAK y se basaron en el típico makemenu, que venia en el pack del tesoro del pirata que es el que conocen todos.

¿Cuántos juegos aguanta por disco? ¿Los 26 de la A a la Z? ¿También son sólo 3 sectores?

por lo que me acuerdo 26, lo cual es suficiente para 1030 sectores libres, mas usa los 3 sectores boot que es lo standar. también tiene el basic desabilitado por defecto, o sea que no es necesario cargar con OPTION los games.

En todo caso, lo que dogdark me vio hacer fue un merge de dos ATRs

Claro, pero nunca esta demás una herramienta así ajaajajja

Saludos

[vitoco]

No me aguanté y bajé tu programita para sapearlo... me encontré con lo siguiente:

• El ATR siempre tiene el mismo nombre "menu.atr" y al parecer lo crea en el mismo directorio donde corre el EXE. Como que le falta el "Guardar como..."
• El ATR queda "corrupto", es decir, le sobra un byte al final con valor $4D ("M").
• El menu carga en la dirección $0700, pero inicializa el DOSINI en $087F. Eso no tiene sentido porque cae justo encima de donde va la lista de juegos en la pantalla, pero creo que pensaron que lo que se indicaba en esa parte (bytes +4 y +5 del 1er sector) era el último byte de los 3 bloques, como si fuera un XEX con dirección "desde" y "hasta".
• El menu efectivamente deshabilita el BASIC (y los bancos de memoria). Supongo que por eso les dió lo mismo lo del DOSINI.
• A pesar que puse mayúsculas y minúsculas en los 20 caracteres que el programa pide para el título, me las dejó todas en minúscula (del mismo color en el menú).

Ups, se me acabó el recreo... eso por ahora.

[AsCrNet]

Gracias vitoco por tu feedback

• El ATR siempre tiene el mismo nombre "menu.atr" y al parecer lo crea en el mismo directorio donde corre el EXE. Como que le falta el "Guardar como..."

Así fue hecho, no había presupuesto para mas jajjjajaja es que lo hice de forma liviana usando dev-cpp con la api nativa de Win. ya que tenia como 2 horas libres en la peguita

• El ATR queda "corrupto", es decir, le sobra un byte al final con valor $4D ("M").

buggggggggggggggggggggggg seguramente lo agrega al grabar el ATR, vamos a revisar.

• El menu carga en la dirección $0700, pero inicializa el DOSINI en $087F. Eso no tiene sentido porque cae justo encima de donde va la lista de juegos en la pantalla, pero creo que pensaron que lo que se indicaba en esa parte (bytes +4 y +5 del 1er sector) era el último byte de los 3 bloques, como si fuera un XEX con dirección "desde" y "hasta".

te adjunto el fuente en ASM para que salgas de tus dudas.

Spoiler: MOSTRAR

Código: Seleccionar todo

	org $0706
;
INICIO
	LDA #0
	STA $47
	STA $48
	STA SW.1
	TAY 
;
    LDA #15
	STA 711
	LDA #28
	STA 709
;APAGAR BASIC
	LDA #$FF
	STA $D301
	STA $03F8
;INSTALAR NUEVA LISTA
	LDA # <LISTA
	STA $0230
	LDA # >LISTA
	STA $0231
;SECTOR DE DIRECTORIO 361($0169)
	LDA #$69
	STA $18
;
DIRECTORIO
	LDA $18
	STA DVTBL+$0A
	LDA #$01
	STA DVTBL+$0B
	INC $18
	JSR LEE.SECTOR
PONE.NOMBRE
	LDA BUFFER,Y
;ULTIMO ARCHIVO
	BEQ TECLA
;ARCHIVO BORRADO
	BMI OTRO
;ARCHIVO VALIDO
	LDX $47
	LDA BUFFER+3,Y
	STA SECTOR.LOW,X
	LDA BUFFER+4,Y
	STA SECTOR.HIG,X
	TXA 
	CLC 
	ADC #$A1 	; suma para otro color
;IDENTIFICADOR DEL ARCHIVO
	LDX $48
;CARACTERES DEL NOMBRE
	STA PANTALLA,X
	LDA #$08
	STA $49
;NOMBRE A PANTALLA
NOMBRE
	LDA BUFFER+5,Y
	SEC 
	SBC #$20
	STA PANTALLA+1,X
	INY 
	INX 
	DEC $49
	BNE NOMBRE
	TYA 
	SEC 
	SBC #$08
	TAY 
	TXA 
	CLC 
	ADC #$02
	STA $48
	INC $47
	LDA $47
;NUMERO MAXIMO DE ARCHIVOS
	CMP #24
	BEQ TECLA
OTRO
	TYA 
	CLC 
	ADC #$10
	TAY 
	ASL
	BCC PONE.NOMBRE
	BCS DIRECTORIO
TECLA
	JSR $F2FD ;LEE.TECLA
NOESCAPE
	SEC 
	SBC #$41
	CMP $47
	BCS TECLA
	TAX 
	LDA SECTOR.LOW,X
	STA DVTBL+$0A
	LDA SECTOR.HIG,X
	STA DVTBL+$0B
	JSR LEE.SECTOR
	DEX 
LOOP.BYTE
	JSR CONTROL
	STA $43
	JSR CONTROL
	STA $44
	AND $43
	CMP #$FF
	BEQ LOOP.BYTE
	LDA SW.1
	BNE SIGUE.1
	LDA $43
	STA $02E0
	LDA $44
	STA $02E1
	INC SW.1
SIGUE.1
	JSR CONTROL
	STA $45
	JSR CONTROL
	STA $46
BLOQUE
	JSR CONTROL
	STA ($43),Y
	INC $43
	BNE NO.CERO
	INC $44
NO.CERO
	LDA $45
	CMP $43
	LDA $46
	SBC $44
	BCS BLOQUE
	LDA $02E2
	ORA $02E3
	BEQ LOOP.BYTE
	STX $19
	JSR DIREC.INI
	LDX $19
	LDY #$00
	STY $02E2
	STY $02E3
	BEQ LOOP.BYTE
DIREC.INI
	JMP ($02E2)
CONTROL
	CPX #$7D
	BNE TOMA.BYTE
	LDA DVTBL+$0A
	ORA DVTBL+$0B
	BNE LEE.SECTOR
	JMP ($02E0) 	;Salto Final!
LEE.SECTOR
	LDX #$0B
LLENA.TABLA
	LDA DVTBL,X
	STA $0300,X 	;DDEVIC
	DEX 
	BPL LLENA.TABLA
LEE.2
	JSR $E453 	; SIOV
	BMI LEE.2 	; Error, relee!
	LDA BUFFER+$7D
	AND #$03
	STA DVTBL+$0B
	LDA BUFFER+$7E
	STA DVTBL+$0A
	LDA BUFFER+$7F
	AND #$7F
	STA CONTROL+1
	LDY #$00
	LDX #$00
TOMA.BYTE
	LDA BUFFER,X
	INX 
	RTS 
DVTBL
	.BYTE $31,$01,$52,$40
	.BYTE  <BUFFER, >BUFFER,$10,$00
	.BYTE $80,$00,$00,$00
SW.1	.BYTE $00
LISTA
	.BYTE $70,$70,$70,$70
	.BYTE $47
	.WORD TITULO
	.BYTE $70,$70,$70
LINE
	.BYTE $06,$06,$06,$06,$06
	.BYTE $06,$06,$06,$06,$06
	.BYTE $06,$06,$41
	.WORD LISTA
TITULO
	DTA d" menuboot "
	DTA d"atariware "*
PANTALLA
	org $0980
BUFFER
	org *+128
SECTOR.LOW
	org *+30
SECTOR.HIG

• El menu efectivamente deshabilita el BASIC (y los bancos de memoria). Supongo que por eso les dió lo mismo lo del DOSINI.

Así es.

• A pesar que puse mayúsculas y minúsculas en los 20 caracteres que el programa pide para el título, me las dejó todas en minúscula (del mismo color en el menú).

Así esta hecho jajajajajaaj

Saludos

[AsCrNet]

ya nueva versión 1.1

• El ATR queda "corrupto", es decir, le sobra un byte al final con valor $4D ("M").

BUG reparado.....

• A pesar que puse mayúsculas y minúsculas en los 20 caracteres que el programa pide para el título, me las dejó todas en minúscula (del mismo color en el menú).

Revise el código y por algún motivo lo deje fijo que no me acuerdo , pero ya puede usar mayúsculas y minúsculas don vitoco.

Saludos

[vitoco]

Ahora se ve bonito... el amarillo en el título se ve más "canario" en Altirra que lo que muestra la captura en tu sitio.

• El ATR siempre tiene el mismo nombre "menu.atr" y al parecer lo crea en el mismo directorio donde corre el EXE. Como que le falta el "Guardar como..."

Así fue hecho, no había presupuesto para mas jajjjajaja es que lo hice de forma liviana usando dev-cpp con la api nativa de Win. ya que tenia como 2 horas libres en la peguita
[/list]

¿Y esa API no tiene el "Guardar como..."? Hasta donde cacho, la WinAPI estándar tiene el diálogo para abrir y para guardar. Échale un luk'in cuando tengas un par más de horas libres en la pega.

[Suppawer]

ya nueva versión 1.1

Genial como siempre.
¿No se podría (digo yo), generar un espacio o un guión entre la letra y el nombre?. A ojos rápidos, se desvirtúa un poco el nombre del juego. Ej:


En vez de ET, pareciera decir BET

[vitoco]

¿No so podría (digo yo), generar un espacio o un guión entre la letra y el nombre?. A ojos rápidos, se desvirtúa un poco el nombre del juego.

No hay espacio, son 20 caracteres máximo por línea:
1 letra + 8 del nombre + 1 espacio + 1 letra + 8 del nombre = 19
y se requieren 2 más para insertar el espacio (o un "dos puntos" o guión) entre la letra y el nombre, es decir 21.

Claro, a menos que cambie el playfield a wide y ocupe un poco de los márgenes.

Y eso que no está usando los 3 caracteres de la extensión del archivo (que en esa época no era XEX).

[AsCrNet]

Ahora se ve bonito... el amarillo en el título se ve más "canario" en Altirra que lo que muestra la captura en tu sitio.

claro, pero la captura es desde el mismo altirra

¿Y esa API no tiene el "Guardar como..."? Hasta donde cacho, la WinAPI estándar tiene el diálogo para abrir y para guardar. Échale un luk'in cuando tengas un par más de horas libres en la pega.

obvio que la tiene lo que pasa usando la api win32 nativa es mas difícil de usar pero no imposible, ya actualice pruebala "Ahora encuentro la razón a las personas que decían que era un cacho programar con la api nativa de windows!!!, la idea que fuera como un crack de aplicación que no necesite ninguna DLL externa."

¿No so podría (digo yo), generar un espacio o un guión entre la letra y el nombre?. A ojos rápidos, se desvirtúa un poco el nombre del juego.

No hay espacio, tal como dice el colega vitoco.

.... a menos que cambie el playfield a wide y ocupe un poco de los márgene

ummm no se si daría y también se haría el programa mas largo, eso es un problema por que me pasaría de los 3 sectores que tengo para el menu.

Saludos